package {
 	import com.oreilly.utils.TokenUtil;
 	
 	import flash.display.Sprite;
 
 	public class TokenTutorial extends Sprite
 	{
  		public function TokenTutorial()
  		{
   			demo1();
   			demo2();
   		}
  		
  		/**
  		 * Demo 1 shows you how we can take a string and replace values inside
  		 * of it by running it through the TokenUtil.
  		 */		
  		public function demo1():void
  		{
   			var sampleText:String = "Hello ${text}, ${message}.";
   			
   			var token:Object = { text: "World", message: "this is my token demo" };
   			
   			var replacedText:String = TokenUtil.replaceTokens(sampleText, token);
   			
   			trace( "Demo 1 - String Replace:" );
   			trace( "Original Text: ", sampleText );
   			trace( "Replaced Text: ", replacedText, "\n" );
   		}
  		
  		/**
  		 * Demo 2 shows you how you can take a api call, and dynamically change
  		 * parameters in it through the TokenUtil.
  		 */		
  		public function demo2():void
  		{
   			var twitterAPI:String = "http://twitter.com/statuses/${method}/${user}.xml";
   			
   			var token:Object = { method: "user_timeline", user: "theflashbum" };
   			
   			var replacedAPI:String = TokenUtil.replaceTokens(twitterAPI, token);
   			
   			trace( "Demo 2 - Twitter API Call:" );
   			trace( "Original Text: ", twitterAPI );
   			trace( "Replaced Text: ", replacedAPI, "\n" );
   		}
  	}
}

 
package com.oreilly.utils
{
 	public class TokenUtil
 	{
  		public static const CURLY_BRACES_PATTERN:RegExp = /\$\{([\w'-]+)\}/g;
   		public static const BRACKET_PATTERN:RegExp = /\$\[([\w'-]+)\]/g;
   		
   		/**
   		 * This util will take a string, search for ${tokens} and replace them 
   		 * with the values in the supplied object.
   		 * @param text - text you would like to search for tokens
   		 * @param paramObj - an object to use to find and replace tokens with
   		 * @param replaceUndefineds - string to use when undefined are found
   		 * @param overrideRegEx - override the default regex pattern
   		 * @return 
   		 * 
   		 */		
   		public static function replaceTokens(text:String, paramObj: Object = null, replaceUndefineds:String = "", overrideRegEx:RegExp = null) : String{
    		    if(!paramObj){
     		    	return text;
     		    }else{
     		    	var myRegEx:RegExp = overrideRegEx ? overrideRegEx : CURLY_BRACES_PATTERN;
     		   		
     		   		var cleanText:String = text.replace(myRegEx,function():*{return paramObj[arguments[1]]});
     			
     				cleanText = cleanText.replace(/undefined/gi,replaceUndefineds);
     					
     		   		return cleanText;
     		   		
     		    }
    		}
   		
   	}
 }