<?xml version="1.0" encoding="UTF-8"?>
<config>
	<URIs handler="parseURIs">
		<URI name="locations"><![CDATA[xml/locations/${filename}.xml]]></URI>
		<URI name="fonts"><![CDATA[swfs/fonts/${filename}.swf]]></URI>
		<URI name="css"><![CDATA[css/${filename}.css]]></URI>
		<URI name="decalsheets"><![CDATA[xml/${filename}.xml]]></URI>
		<URI name="selectContainer"><![CDATA[${location}/container/${id}/view/front]]></URI>
	</URIs>
</config>

package com.flashartofwar.utils
{
 
 	/**
 	 * 
 	 */
 	public class URIManagerUtil
 	{
  		private static var __instance : URIManagerUtil;
  		private var uris : Array = [];
  
  		/**
  		 * Constructor can only be called by the static instance method.
  		 * 
  		 */
  		public function URIManagerUtil(enforcer : SingletonEnforcer)
  		{       
   			if (enforcer == null) 
   			{
    				throw new Error( "Error: Instantiation failed: Use URIManagerUtil.instance instead." );
    			}
   		}
  
  		/**
  		 * Creates a new instance of URIManagerUtil if one does not currently exist.
  		 * 
  		 * @return URIManagerUtil
  		 */   
  		public static function get instance() : URIManagerUtil
  		{
   			if(URIManagerUtil.__instance == null) 
   			{
    				URIManagerUtil.__instance = new URIManagerUtil( new SingletonEnforcer( ) );
    			}
   			return URIManagerUtil.__instance;
   		}
  
  		/**
  		 * Use this method to add a URI into the utility.
  		 * 
  		 * @param name this is the name of the URI. You will need to use this
  		 * when requesting a URI from the utility.
  		 * @param path the path of the URI. You can put ${tokens} in the path
  		 * to be used when requesting out later.
  		 */
  		public function addURI( name : String, path : String ) : void
  		{
   			uris[ name ] = path;
   		}       
  
  		/**
  		 * This returns a URI from the manager. 
  		 * 
  		 * @param name this is the name of the URI
  		 * @param token this is the object that contains values to use to 
  		 * replace tokens in the url. Each property of the object will be
  		 * tested against a ${token} with a similar name. If a match is
  		 * found, the properties value will replace the token.
  		 */
  		public function getURI( name : String, token : Object = null ) : String
  		{
   			var uriMethod : String = "";
                           
   			uriMethod = uris[ name ] ? uris[ name ] : "";
                           
   			return TokenUtil.replaceTokens( uriMethod, token );
   		}               
  	}
}

internal class SingletonEnforcer 
{
}

package 
{
 	import com.flashartofwar.utils.URIManagerUtil;
 
 	import flash.net.URLRequest;
 	import flash.events.Event;
 	import flash.net.URLLoader;
 	import flash.display.Sprite;
 
 	/**
 	 * @author jessefreeman
 	 */
 	public class URIManagerExamples extends Sprite 
 	{
  		private var loader : URLLoader;
  		private var URIManager : URIManagerUtil;
  
  		public function URIManagerExamples() 
  		{
   			
   			loadConfig( );
   		}
  
  		private function loadConfig() : void
  		{
   			loader = new URLLoader( );
   			loader.addEventListener( Event.COMPLETE, onConfigLoad );
   			loader.load( new URLRequest( "xml/config.xml" ) );
   		}
  
  		private function onConfigLoad(event : Event) : void 
  		{
   			parseURIs( XML( event.target.data ) );
   		}
  
  		private function parseURIs(xml : XML) : void 
  		{
   			
   			var URIList : XMLList = xml.URIs.*;
   			
   			URIManager = URIManagerUtil.instance;
   			var URI : XML;
   			
   			for each (URI in URIList) 
   			{
    				URIManager.addURI( URI.@name, URI.toString( ) );
    			}
   			
   			testURIManager( );
   		}
  
  		private function testURIManager() : void 
  		{
   			
   			// Test 1
   			trace( "locations \n", URIManager.getURI( "locations" ) + "\n", URIManager.getURI( "locations", {filename: "eastvillage"} ), "\n" );
   			
   			// Test 2
   			trace( "fonts \n", URIManager.getURI( "fonts" ) + "\n", URIManager.getURI( "fonts", {filename: "FontLibrary"} ), "\n" );
   			
   			// Test 3
   			trace( "selectContainer \n", URIManager.getURI( "selectContainer" ) + "\n", URIManager.getURI( "selectContainer", {location: "eastvillage", id:"1"} ), "\n" );
   		}
  	}
}